*Pillar 3 - Analysing VACS data*
*Session 3.6 - Constructing and coding emotional violence*




*Step by step guide of how to construct emotional violence variables*


*In this guide, we will be coding a emotional violence variable using the Cote d'Ivoire VACS data. There are lots of different emotional violence variables you might want to code in the data depending on timeframe, perpetrator and acts. We are going to be looking at some different examples of coding emotional violence. 




*******************************************************************************
*Setting up your data
*******************************************************************************
*Cote d'Ivoire only has one dataset for all individuals, but note that some countries have separate datasets for males and females. If they are separate, depending on the analysis you are doing, you can either analyse them separately or merge the datasets before analysing them.


*Set your working directory to the file location where you would like to save all files for your project, and load the dataset into stata. 
*cd "..."
use CotedIvoire_pubuse_031522.dta


*Make all the variables lower case. This will make it easier to code as Stata is case sensitive and the VACS survey has some variables in upper and some in lower case. 
rename *, lower        


*******************************************************************************
*Surveyset your data
*******************************************************************************
*Now we need to surveyset our data to account for the complex sampling strategy used in the VACS surveys.


*For Cote d'Ivoire, the stratification, cluster, and sample weight variables are strata, psu, EA, and sampleweight, respectively. Note that this varies by survey and you will need to check the variables for your country survey. The data summary file that you will receive with the dataset details this. 
gen weight=sampleweight
svyset psu [pweight=weight], strata(strata) vce(linearized) singleunit(centered)




*******************************************************************************
*Generate labels for your variables
*******************************************************************************
*Here we generate labels for the variables that we plan to create. You can keep adding to this as you create all your variables, but it can help to have all the labels organised in a separate place to your variables.


*Yes/No label (the version in the data is 1=yes, 2=No, 99=Don't know/declined) 
label define yesno 0 "No" 1 "Yes" 99 "DK/declined", replace 


*Age of first exposure
label define exposureage_4cat 0 "0-5 years" 1 "6-11 years" 2 "12-17 years" 3 "18-24 years" 99 "Don't know/declined", replace // in four categories
label define exposureage_3cat 0 "under 12 years" 1 "12-17 years" 2 "18-24 years" 99 "Don't know/declined", replace // in three categories
label define exposureage 0 "0-17 years" 1 "18-24 years" 99 "Don't know/declined", replace // in two categories
                
*Demographics
label define sex 1 "male" 2 "female"
label define age_binary 0"13-17 years" 1"18-24 years"




**********************************************************************************
*Create variables your demographics
**********************************************************************************
*It can be useful to start by creating or cleaning variables for demographics that you know will be important in your analysis. Age and sex are included here, but there are likely to be more that you will want to code.


*Age - this could be a continuous, binary or categorical variable. Here, we create a binary variable for 13-17 year olds vs 18-24 year olds. 
clonevar age=q2 // this would be a continuous measure of respondent age
gen age_binary=0 // this would be a binary variable where 0=13-17 years and 1=18-24 years
replace age_binary=1 if inrange(age,18,24) 
label values age_binary age_binary
tab age age_binary // always remember to tabulate your new variable against the existing variable to check for any errors you may have made when creating the variable.


*Sex - there is already a variable. Here we label the values of the variable to make it easier to see which group represents males and which represents females.
label values sex sex


***************************************************************************************
*Creating the violence variable
***************************************************************************************


***************************************************************************************
*Example: Ever experiencing emotional violence from a parent, adult caregiver or adult relative
***************************************************************************************


*The survey includes the following three acts of violence for each perpetrator, for example for lifetime peer violence, the items are: 
*q116: Has a person your own age ever:
        *q300a Told you you were not loved or did not deserve to be loved?
        *q300b Told you they wished you had never been born or were dead?‚Äãct?
        *q300c Ridiculed you or put you down (e.g. told you you were stupid or useless)?‚Äã
        *1=yes, 2=no, 99=dk/dta 
        
***************************************************************************************
*STEP 1: Construct a measure of any lifetime emotional violence
***************************************************************************************
*Here, we will construct a variable for lifetime experience of any physical violence from a caregiver.


*Lifetime emotional violence from a caregiver
gen ev_ever=0
replace ev_ever=1 if q300a==1 | q300b==1 | q300c==1
replace ev_ever=. if inlist(q300a,99,.,98) & inlist(q300b,99,.,98) & inlist(q300c,99,.,98) // this codes the variable as 'missing' if the respondent responds 'Don't know' or declined to answer to all four items, or if ALL four items were missing. If an individual responds 'Don't know' or declined to answer for <4 items, or if <4 items are missing, then the individual will be coded as 0 or 1 depending on the answers to the remaining items and the individual would not be coded as missing.
label values ev_ever yesno 


*Then check the variable that you've created
tab ev_ever 
tab1 q300a q300b q300c


*Tabulate the % of all individuals who have experienced any emotional violence from a parent, adult caregiver or adult relative
svy:tab ev_ever, col obs


*Note that some surveys includes additional questions related to emotional violence from other perpetrators, for example intimate partner EV in the past year and bullying by other students in the past 30 days. Some surveys from other countries also include emotional violence from intimate partners in the lifetime. So remember to check what questions were asked in the VACS survey that you are analysing.


***************************************************************************************
*Example 2: Past year emotional violence from peers 
***************************************************************************************
*The Cote d'Ivoire survey measures emotional violence from peers in the past year. Let's look at how to code this. 
gen ev_peer_py=0
replace ev_peer_py=1 if q315a==1 | q315b==1 | q315c==1
replace ev_peer_py=. if inlist(q315a,99,.,98) & inlist(q315b,99,.,98) & inlist(q315c,99,.,98) // this codes the variable as 'missing' if the respondent responds 'Don't know' or declined to answer to all four items, or if ALL four items were missing. If an individual responds 'Don't know' or declined to answer for <4 items, or if <4 items are missing, then the individual will be coded as 0 or 1 depending on the answers to the remaining items and the individual would not be coded as missing.
label values ev_peer_py yesno 


*Then check the variable that you've created
tab ev_peer_py 
tab1 q315a q315b q315c
*Tabulate the % of all individuals who have experienced emotional violence from peer in the past year
svy:tab ev_peer_py, col obs


*You may want to explore the prevalence in particular groups, for example by age or sex. For example, we could look at the prevalence of experiencing emotional violence from a peer in the past year among 13-17 year old boys.
svy:tab ev_peer_py if sex==1 & age_bin==0, col obs


*It would not be helpful to combine the variables for emotional violence from a caregiver and emotional violence from a peer in Cote d'Ivoire, given that in this survey they measure violence across different timeframes.